ERRORE PROGETTO STAZIONE METEO v1.0

Nel progetto stazione meteo esce nella compilazione" LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);"POSITIVE was declared in this scope.Cosa devo fare.Grazie e complimenti per l'aggiornamento del sito.


>> Come realizzare una stazione meteo con Arduino - v1.0

Ciao @papat, nel progetto usi un semplice display LCD oppure un display LCD con interfaccia I2C? Nel primo caso saranno necessarie delle piccole modifiche nel codice mentre nel secondo caso, è necessario che scarichi la libreria dell'I2C. Qui trovi una guida sul display LCD con interfaccia I2C mentre qui puoi scaricare il file .ZIP per scaricare la libreria .

Fammi sapere

uso display semplice ,che modifica devo fare

Ciao, spero che per display "semplice" intendi quello senza moduli aggiuntivi. In tal caso devi sostituire il codice riguardante la parte del display LCD.

Codice:


/* Stazione meteo Arduino v1.0
 *  Poderak - http://www.youtube.com/MartinoLutero
 */ 
#include <LiquidCrystal.h>  //libreria display
#include <dht11.h>
dht11 DHT;
#define DHT11_PIN A3
LiquidCrystal lcd(12, 11, 5, 4, 3, 2); // dichiarazione pin display
int temp=0; //raccoglie misura temperatura
int um=0; //raccoglie misura umidità
int temp_min=0; //si ricorda della temperatura min. registrata
int um_min=0; //si ricorda dell'umidità min. registrata
int temp_max=0; //si ricorda della temperatura max. registrata
int um_max=0; //si ricorda dell'umidità min. registrata
int c1, c2; //variabili iniziali per um_min e temp_min

 void setup() {
  lcd.begin(16,2); //inizializzo il display. Il display LCD usato è 16x2
  Serial.begin(9600);
  lcd.setCursor(0,0); //scritta all'avvio di arduino
  lcd.print(" Stazione meteo ");
  lcd.setCursor(0,1);
  lcd.print("  Poderak v1.0  ");
  delay(2000);
  }

void loop() {
  lcd.clear();
  int chk = DHT.read(DHT11_PIN); //abilito lettura dht11
  temp=DHT.temperature; //raccolgo misura temperatura
  um=DHT.humidity; //raccolgo misura umidità
  //stampo valori sul display lcd  
  lcd.setCursor(0,0);
  lcd.print("Umidita' : ");      
  lcd.print(DHT.humidity,1);
  lcd.print("%");
  lcd.setCursor(0,1);
  lcd.print("Temperat.: ");  
  lcd.print(DHT.temperature,1);
  lcd.print((char)223);
  lcd.print("C");
  delay(3000);
  //riempio  variabili um_min e tem_min per la misura iniziale
  if (c1==0) {
    um_min=um;
  }
  if (c2==0) {
    temp_min=temp;
  }
  
  if (temp>temp_max) {
    temp_max=temp;
  }
  
  if (um>um_max) {
    um_max=um;
  }
  
  if (um_min>=um) {
    um_min=um;
    c1++;
  }

  if (temp_min>=temp) {
    temp_min=temp;
    c2++;
  }
 //stampo statistiche: um_max, um_min, temp_max, temp_min
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Umid. max.: ");          
  lcd.print(um_max);
  lcd.print("%");
  lcd.setCursor(0,1);
  lcd.print("Temp. max.: ");  
  lcd.print(temp_max);
  lcd.print((char)223);
  lcd.print("C");
  delay(3000);  
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Umid. min.: ");          
  lcd.print(um_min);
  lcd.print("%");
  lcd.setCursor(0,1);
  lcd.print("Temp. min.: ");  
  lcd.print(temp_min);
  lcd.print((char)223);
  lcd.print("C");
  delay(3000);

  
}

In pratica ho sostituito la libreria con quella classica e ho cambiato la dichiarazione dei PIN. Fammi sapere se funziona

non ho provato,ma dimmi quale libreria hai usato e quale pin hai cambiato.Grazie

In pratica ho tolto questa libreria:

Codice:

#include <LiquidCrystal_I2C.h>

e l'ho sostituita con:

Codice:

#include <LiquidCrystal.h>

Perché? La prima libreria serve per gestire un display LCD con interfaccia I2C. Se usi invece un display normale senza nessun modulo, puoi tranquillamente usare le librerie di default dell'IDE di Arduino.
Inoltre ho sostituito:

Codice:

LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

con:

Codice:

LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

Perché? Sempre per il motivo di prima. I numeri presenti all'interno della funzione rappresentano il posizionamento dei PIN del display collegato con l'Arduino .
Questo è lo schema che devi seguire:

Scopri di più sul display LCD normale qui.